init

fish/.gitignore

@@ -0,0 +1 @@
+local.fish

fish/completions/fzf_configure_bindings.fish

@@ -0,0 +1,8 @@
+complete fzf_configure_bindings --no-files
+complete fzf_configure_bindings --long help --short h --description "Print help" --condition "not __fish_seen_argument --help -h"
+complete fzf_configure_bindings --long directory --description "Change the key binding for Search Directory" --condition "not __fish_seen_argument --directory"
+complete fzf_configure_bindings --long git_log --description "Change the key binding for Search Git Log" --condition "not __fish_seen_argument --git_log"
+complete fzf_configure_bindings --long git_status --description "Change the key binding for Search Git Status" --condition "not __fish_seen_argument --git_status"
+complete fzf_configure_bindings --long history --description "Change the key binding for Search History" --condition "not __fish_seen_argument --history"
+complete fzf_configure_bindings --long processes --description "Change the key binding for Search Processes" --condition "not __fish_seen_argument --processes"
+complete fzf_configure_bindings --long variables --description "Change the key binding for Search Variables" --condition "not __fish_seen_argument --variables"

fish/conf.d/fzf.fish

@@ -0,0 +1,28 @@
+# fzf.fish is only meant to be used in interactive mode. If not in interactive mode and not in CI, skip the config to speed up shell startup
+if not status is-interactive && test "$CI" != true
+    exit
+end
+
+# Because of scoping rules, to capture the shell variables exactly as they are, we must read
+# them before even executing _fzf_search_variables. We use psub to store the
+# variables' info in temporary files and pass in the filenames as arguments.
+# This variable is global so that it can be referenced by fzf_configure_bindings and in tests
+set --global _fzf_search_vars_command '_fzf_search_variables (set --show | psub) (set --names | psub)'
+
+
+# Install the default bindings, which are mnemonic and minimally conflict with fish's preset bindings
+fzf_configure_bindings
+
+# Doesn't erase autoloaded _fzf_* functions because they are not easily accessible once key bindings are erased
+function _fzf_uninstall --on-event fzf_uninstall
+    _fzf_uninstall_bindings
+
+    set --erase _fzf_search_vars_command
+    functions --erase _fzf_uninstall _fzf_migration_message _fzf_uninstall_bindings fzf_configure_bindings
+    complete --erase fzf_configure_bindings
+
+    set_color cyan
+    echo "fzf.fish uninstalled."
+    echo "You may need to manually remove fzf_configure_bindings from your config.fish if you were using custom key bindings."
+    set_color normal
+end

fish/config.fish

@@ -0,0 +1,14 @@
+if status is-interactive
+     set -g fish_key_bindings fish_vi_key_bindings
+     starship init fish | source
+end
+
+ set -U fish_greeting
+
+ abbr lzg lazygit
+ abbr lzd lazydocker
+ abbr hist "history | fzf | fish_clipboard_copy"
+
+ if test -f "$HOME/.config/fish/local.fish"
+     source "$HOME/.config/fish/local.fish"
+ end

fish/fish_plugins

@@ -0,0 +1,2 @@
+patrickf1/fzf.fish
+dracula/fish

fish/fish_variables

@@ -0,0 +1,37 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR __fish_initialized:3800
+SETUVAR _fisher_dracula_2F_fish_files:\x7e/\x2econfig/fish/themes/Dracula\x20Official\x2etheme\x1e\x7e/\x2econfig/fish/conf\x2ed/dracula\x2efish
+SETUVAR _fisher_patrickf1_2F_fzf_2E_fish_files:\x7e/\x2econfig/fish/functions/_fzf_configure_bindings_help\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_extract_var_info\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_preview_changed_file\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_preview_file\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_report_diff_type\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_report_file_type\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_directory\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_git_log\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_git_status\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_history\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_processes\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_search_variables\x2efish\x1e\x7e/\x2econfig/fish/functions/_fzf_wrapper\x2efish\x1e\x7e/\x2econfig/fish/functions/fzf_configure_bindings\x2efish\x1e\x7e/\x2econfig/fish/conf\x2ed/fzf\x2efish\x1e\x7e/\x2econfig/fish/completions/fzf_configure_bindings\x2efish
+SETUVAR _fisher_plugins:patrickf1/fzf\x2efish\x1edracula/fish
+SETUVAR _fisher_upgraded_to_4_4:\x1d
+SETUVAR fish_color_autosuggestion:brblack
+SETUVAR fish_color_cancel:\x2dr
+SETUVAR fish_color_command:blue
+SETUVAR fish_color_comment:red
+SETUVAR fish_color_cwd:green
+SETUVAR fish_color_cwd_root:red
+SETUVAR fish_color_end:green
+SETUVAR fish_color_error:brred
+SETUVAR fish_color_escape:brcyan
+SETUVAR fish_color_history_current:\x2d\x2dbold
+SETUVAR fish_color_host:normal
+SETUVAR fish_color_host_remote:yellow
+SETUVAR fish_color_normal:normal
+SETUVAR fish_color_operator:brcyan
+SETUVAR fish_color_param:cyan
+SETUVAR fish_color_quote:yellow
+SETUVAR fish_color_redirection:cyan\x1e\x2d\x2dbold
+SETUVAR fish_color_search_match:white\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_status:red
+SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_valid_path:\x2d\x2dunderline
+SETUVAR fish_greeting:\x1d
+SETUVAR fish_key_bindings:fish_default_key_bindings
+SETUVAR fish_pager_color_completion:normal
+SETUVAR fish_pager_color_description:yellow\x1e\x2di
+SETUVAR fish_pager_color_prefix:normal\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
+SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan
+SETUVAR fish_pager_color_selected_background:\x2dr
+SETUVAR fish_user_paths:/opt/homebrew/bin

fish/functions/_fzf_configure_bindings_help.fish

@@ -0,0 +1,43 @@
+function _fzf_configure_bindings_help --description "Prints the help message for fzf_configure_bindings."
+    echo "\
+USAGE:
+    fzf_configure_bindings [--COMMAND=[KEY_SEQUENCE]...]
+
+DESCRIPTION
+    fzf_configure_bindings installs key bindings for fzf.fish's commands and erases any bindings it
+    previously installed. It installs bindings for both default and insert modes. fzf.fish executes
+    it without options on fish startup to install the out-of-the-box key bindings.
+
+    By default, commands are bound to a mnemonic key sequence, shown below. Each command's binding
+    can be configured using a namesake corresponding option:
+        COMMAND            |  DEFAULT KEY SEQUENCE         |  CORRESPONDING OPTION
+        Search Directory   |  Ctrl+Alt+F (F for file)      |  --directory
+        Search Git Log     |  Ctrl+Alt+L (L for log)       |  --git_log
+        Search Git Status  |  Ctrl+Alt+S (S for status)    |  --git_status
+        Search History     |  Ctrl+R     (R for reverse)   |  --history
+        Search Processes   |  Ctrl+Alt+P (P for process)   |  --processes
+        Search Variables   |  Ctrl+V     (V for variable)  |  --variables
+    Override a command's binding by specifying its corresponding option with the desired key
+    sequence. Disable a command's binding by specifying its corresponding option with no value.
+
+    Because fzf_configure_bindings erases bindings it previously installed, it can be cleanly
+    executed multiple times. Once the desired fzf_configure_bindings command has been found, add it
+    to your config.fish in order to persist the customized bindings.
+
+    In terms of validation, fzf_configure_bindings fails if passed unknown options. It expects an
+    equals sign between an option's name and value. However, it does not validate key sequences.
+
+    Pass -h or --help to print this help message and exit.
+
+EXAMPLES
+    Default bindings but bind Search Directory to Ctrl+F and Search Variables to Ctrl+Alt+V
+        \$ fzf_configure_bindings --directory=\cf --variables=\e\cv
+    Default bindings but disable Search History
+        \$ fzf_configure_bindings --history=
+    An agglomeration of different options
+        \$ fzf_configure_bindings --git_status=\cg --history=\ch --variables= --processes=
+
+SEE Also
+    To learn more about fish key bindings, see bind(1) and fish_key_reader(1).
+"
+end

fish/functions/_fzf_extract_var_info.fish

@@ -0,0 +1,15 @@
+# helper function for _fzf_search_variables
+function _fzf_extract_var_info --argument-names variable_name set_show_output --description "Extract and reformat lines pertaining to \$variable_name from \$set_show_output."
+    # Extract only the lines about the variable, all of which begin with either
+    # $variable_name: ...or... $variable_name[
+    string match --regex "^\\\$$variable_name(?::|\[).*" <$set_show_output |
+
+        # Strip the variable name prefix, including ": " for scope info lines
+        string replace --regex "^\\\$$variable_name(?:: )?" '' |
+
+        # Distill the lines of values, replacing...
+        #   [1]: |value|
+        # ...with...
+        #   [1] value
+        string replace --regex ": \|(.*)\|" ' $1'
+end

fish/functions/_fzf_preview_changed_file.fish

@@ -0,0 +1,49 @@
+# helper for _fzf_search_git_status
+# arg should be a line from git status --short, e.g.
+# MM functions/_fzf_preview_changed_file.fish
+#  D README.md
+# R  LICENSE -> "New License"
+function _fzf_preview_changed_file --argument-names path_status --description "Show the git diff of the given file."
+    # remove quotes because they'll be interpreted literally by git diff
+    # no need to requote when referencing $path because fish does not perform word splitting
+    # https://fishshell.com/docs/current/fish_for_bash_users.html
+    set -f path (string unescape (string sub --start 4 $path_status))
+    # first letter of short format shows index, second letter shows working tree
+    # https://git-scm.com/docs/git-status/2.35.0#_short_format
+    set -f index_status (string sub --length 1 $path_status)
+    set -f working_tree_status (string sub --start 2 --length 1 $path_status)
+
+    set -f diff_opts --color=always
+
+    if test $index_status = '?'
+        _fzf_report_diff_type Untracked
+        _fzf_preview_file $path
+    else if contains {$index_status}$working_tree_status DD AU UD UA DU AA UU
+        # Unmerged statuses taken directly from git status help's short format table
+        # Unmerged statuses are mutually exclusive with other statuses, so if we see
+        # these, then safe to assume the path is unmerged
+        _fzf_report_diff_type Unmerged
+        git diff $diff_opts -- $path
+    else
+        if test $index_status != ' '
+            _fzf_report_diff_type Staged
+
+            # renames are only detected in the index, never working tree, so only need to test for it here
+            # https://stackoverflow.com/questions/73954214
+            if test $index_status = R
+                # diff the post-rename path with the original path, otherwise the diff will show the entire file as being added
+                set -f orig_and_new_path (string split --max 1 -- ' -> ' $path)
+                git diff --staged $diff_opts -- $orig_and_new_path[1] $orig_and_new_path[2]
+                # path currently has the form of "original -> current", so we need to correct it before it's used below
+                set path $orig_and_new_path[2]
+            else
+                git diff --staged $diff_opts -- $path
+            end
+        end
+
+        if test $working_tree_status != ' '
+            _fzf_report_diff_type Unstaged
+            git diff $diff_opts -- $path
+        end
+    end
+end

fish/functions/_fzf_preview_file.fish

@@ -0,0 +1,43 @@
+# helper function for _fzf_search_directory and _fzf_search_git_status
+function _fzf_preview_file --description "Print a preview for the given file based on its file type."
+    # because there's no way to guarantee that _fzf_search_directory passes the path to _fzf_preview_file
+    # as one argument, we collect all the arguments into one single variable and treat that as the path
+    set -f file_path $argv
+
+    if test -L "$file_path" # symlink
+        # notify user and recurse on the target of the symlink, which can be any of these file types
+        set -l target_path (realpath "$file_path")
+
+        set_color yellow
+        echo "'$file_path' is a symlink to '$target_path'."
+        set_color normal
+
+        _fzf_preview_file "$target_path"
+    else if test -f "$file_path" # regular file
+        if set --query fzf_preview_file_cmd
+            # need to escape quotes to make sure eval receives file_path as a single arg
+            eval "$fzf_preview_file_cmd '$file_path'"
+        else
+            bat --style=numbers --color=always "$file_path"
+        end
+    else if test -d "$file_path" # directory
+        if set --query fzf_preview_dir_cmd
+            # see above
+            eval "$fzf_preview_dir_cmd '$file_path'"
+        else
+            # -A list hidden files as well, except for . and ..
+            # -F helps classify files by appending symbols after the file name
+            command ls -A -F "$file_path"
+        end
+    else if test -c "$file_path"
+        _fzf_report_file_type "$file_path" "character device file"
+    else if test -b "$file_path"
+        _fzf_report_file_type "$file_path" "block device file"
+    else if test -S "$file_path"
+        _fzf_report_file_type "$file_path" socket
+    else if test -p "$file_path"
+        _fzf_report_file_type "$file_path" "named pipe"
+    else
+        echo "$file_path doesn't exist." >&2
+    end
+end

fish/functions/_fzf_report_diff_type.fish

@@ -0,0 +1,18 @@
+# helper for _fzf_preview_changed_file
+# prints out something like
+# ╭────────╮
+# │ Staged │
+# ╰────────╯
+function _fzf_report_diff_type --argument-names diff_type --description "Print a distinct colored header meant to preface a git patch."
+    # number of "-" to draw is the length of the string to box + 2 for padding
+    set -f repeat_count (math 2 + (string length $diff_type))
+    set -f line (string repeat --count $repeat_count ─)
+    set -f top_border ╭$line╮
+    set -f btm_border ╰$line╯
+
+    set_color yellow
+    echo $top_border
+    echo "│ $diff_type │"
+    echo $btm_border
+    set_color normal
+end

fish/functions/_fzf_report_file_type.fish

@@ -0,0 +1,6 @@
+# helper function for _fzf_preview_file
+function _fzf_report_file_type --argument-names file_path file_type --description "Explain the file type for a file."
+    set_color red
+    echo "Cannot preview '$file_path': it is a $file_type."
+    set_color normal
+end

fish/functions/_fzf_search_directory.fish

@@ -0,0 +1,33 @@
+function _fzf_search_directory --description "Search the current directory. Replace the current token with the selected file paths."
+    # Directly use fd binary to avoid output buffering delay caused by a fd alias, if any.
+    # Debian-based distros install fd as fdfind and the fd package is something else, so
+    # check for fdfind first. Fall back to "fd" for a clear error message.
+    set -f fd_cmd (command -v fdfind || command -v fd  || echo "fd")
+    set -f --append fd_cmd --color=always $fzf_fd_opts
+
+    set -f fzf_arguments --multi --ansi $fzf_directory_opts
+    set -f token (commandline --current-token)
+    # expand any variables or leading tilde (~) in the token
+    set -f expanded_token (eval echo -- $token)
+    # unescape token because it's already quoted so backslashes will mess up the path
+    set -f unescaped_exp_token (string unescape -- $expanded_token)
+
+    # If the current token is a directory and has a trailing slash,
+    # then use it as fd's base directory.
+    if string match --quiet -- "*/" $unescaped_exp_token && test -d "$unescaped_exp_token"
+        set --append fd_cmd --base-directory=$unescaped_exp_token
+        # use the directory name as fzf's prompt to indicate the search is limited to that directory
+        set --prepend fzf_arguments --prompt="Directory $unescaped_exp_token> " --preview="_fzf_preview_file $expanded_token{}"
+        set -f file_paths_selected $unescaped_exp_token($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    else
+        set --prepend fzf_arguments --prompt="Directory> " --query="$unescaped_exp_token" --preview='_fzf_preview_file {}'
+        set -f file_paths_selected ($fd_cmd 2>/dev/null | _fzf_wrapper $fzf_arguments)
+    end
+
+
+    if test $status -eq 0
+        commandline --current-token --replace -- (string escape -- $file_paths_selected | string join ' ')
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_search_git_log.fish

@@ -0,0 +1,36 @@
+function _fzf_search_git_log --description "Search the output of git log and preview commits. Replace the current token with the selected commit hash."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_log: Not in a git repository.' >&2
+    else
+        if not set --query fzf_git_log_format
+            # %h gives you the abbreviated commit hash, which is useful for saving screen space, but we will have to expand it later below
+            set -f fzf_git_log_format '%C(bold blue)%h%C(reset) - %C(cyan)%ad%C(reset) %C(yellow)%d%C(reset) %C(normal)%s%C(reset)  %C(dim normal)[%an]%C(reset)'
+        end
+
+        set -f preview_cmd 'git show --color=always --stat --patch {1}'
+        if set --query fzf_diff_highlighter
+            set preview_cmd "$preview_cmd | $fzf_diff_highlighter"
+        end
+
+        set -f selected_log_lines (
+            git log --no-show-signature --color=always --format=format:$fzf_git_log_format --date=short | \
+            _fzf_wrapper --ansi \
+                --multi \
+                --scheme=history \
+                --prompt="Git Log> " \
+                --preview=$preview_cmd \
+                --query=(commandline --current-token) \
+                $fzf_git_log_opts
+        )
+        if test $status -eq 0
+            for line in $selected_log_lines
+                set -f abbreviated_commit_hash (string split --field 1 " " $line)
+                set -f full_commit_hash (git rev-parse $abbreviated_commit_hash)
+                set -f --append commit_hashes $full_commit_hash
+            end
+            commandline --current-token --replace (string join ' ' $commit_hashes)
+        end
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_search_git_status.fish

@@ -0,0 +1,41 @@
+function _fzf_search_git_status --description "Search the output of git status. Replace the current token with the selected file paths."
+    if not git rev-parse --git-dir >/dev/null 2>&1
+        echo '_fzf_search_git_status: Not in a git repository.' >&2
+    else
+        set -f preview_cmd '_fzf_preview_changed_file {}'
+        if set --query fzf_diff_highlighter
+            set preview_cmd "$preview_cmd | $fzf_diff_highlighter"
+        end
+
+        set -f selected_paths (
+            # Pass configuration color.status=always to force status to use colors even though output is sent to a pipe
+            git -c color.status=always status --short |
+            _fzf_wrapper --ansi \
+                --multi \
+                --prompt="Git Status> " \
+                --query=(commandline --current-token) \
+                --preview=$preview_cmd \
+                --nth="2.." \
+                $fzf_git_status_opts
+        )
+        if test $status -eq 0
+            # git status --short automatically escapes the paths of most files for us so not going to bother trying to handle
+            # the few edges cases of weird file names that should be extremely rare (e.g. "this;needs;escaping")
+            set -f cleaned_paths
+
+            for path in $selected_paths
+                if test (string sub --length 1 $path) = R
+                    # path has been renamed and looks like "R LICENSE -> LICENSE.md"
+                    # extract the path to use from after the arrow
+                    set --append cleaned_paths (string split -- "-> " $path)[-1]
+                else
+                    set --append cleaned_paths (string sub --start=4 $path)
+                end
+            end
+
+            commandline --current-token --replace -- (string join ' ' $cleaned_paths)
+        end
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_search_history.fish

@@ -0,0 +1,39 @@
+function _fzf_search_history --description "Search command history. Replace the command line with the selected command."
+    # history merge incorporates history changes from other fish sessions
+    # it errors out if called in private mode
+    if test -z "$fish_private_mode"
+        builtin history merge
+    end
+
+    if not set --query fzf_history_time_format
+        # Reference https://devhints.io/strftime to understand strftime format symbols
+        set -f fzf_history_time_format "%m-%d %H:%M:%S"
+    end
+
+    # Delinate time from command in history entries using the vertical box drawing char (U+2502).
+    # Then, to get raw command from history entries, delete everything up to it. The ? on regex is
+    # necessary to make regex non-greedy so it won't match into commands containing the char.
+    set -f time_prefix_regex '^.*? │ '
+    # Delinate commands throughout pipeline using null rather than newlines because commands can be multi-line
+    set -f commands_selected (
+        builtin history --null --show-time="$fzf_history_time_format │ " |
+        _fzf_wrapper --read0 \
+            --print0 \
+            --multi \
+            --scheme=history \
+            --prompt="History> " \
+            --query=(commandline) \
+            --preview="string replace --regex '$time_prefix_regex' '' -- {} | fish_indent --ansi" \
+            --preview-window="bottom:3:wrap" \
+            $fzf_history_opts |
+        string split0 |
+        # remove timestamps from commands selected
+        string replace --regex $time_prefix_regex ''
+    )
+
+    if test $status -eq 0
+        commandline --replace -- $commands_selected
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_search_processes.fish

@@ -0,0 +1,32 @@
+function _fzf_search_processes --description "Search all running processes. Replace the current token with the pid of the selected process."
+    # Directly use ps command because it is often aliased to a different command entirely
+    # or with options that dirty the search results and preview output
+    set -f ps_cmd (command -v ps || echo "ps")
+    # use all caps to be consistent with ps default format
+    # snake_case because ps doesn't seem to allow spaces in the field names
+    set -f ps_preview_fmt (string join ',' 'pid' 'ppid=PARENT' 'user' '%cpu' 'rss=RSS_IN_KB' 'start=START_TIME' 'command')
+    set -f processes_selected (
+        $ps_cmd -A -opid,command | \
+        _fzf_wrapper --multi \
+                    --prompt="Processes> " \
+                    --query (commandline --current-token) \
+                    --ansi \
+                    # first line outputted by ps is a header, so we need to mark it as so
+                    --header-lines=1 \
+                    # ps uses exit code 1 if the process was not found, in which case show an message explaining so
+                    --preview="$ps_cmd -o '$ps_preview_fmt' -p {1} || echo 'Cannot preview {1} because it exited.'" \
+                    --preview-window="bottom:4:wrap" \
+                    $fzf_processes_opts
+    )
+
+    if test $status -eq 0
+        for process in $processes_selected
+            set -f --append pids_selected (string split --no-empty --field=1 -- " " $process)
+        end
+
+        # string join to replace the newlines outputted by string split with spaces
+        commandline --current-token --replace -- (string join ' ' $pids_selected)
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_search_variables.fish

@@ -0,0 +1,47 @@
+# This function expects the following two arguments:
+# argument 1 = output of (set --show | psub), i.e. a file with the scope info and values of all variables
+# argument 2 = output of (set --names | psub), i.e. a file with all variable names
+function _fzf_search_variables --argument-names set_show_output set_names_output --description "Search and preview shell variables. Replace the current token with the selected variable."
+    if test -z "$set_names_output"
+        printf '%s\n' '_fzf_search_variables requires 2 arguments.' >&2
+
+        commandline --function repaint
+        return 22 # 22 means invalid argument in POSIX
+    end
+
+    # Exclude the history variable from being piped into fzf because
+    # 1. it's not included in $set_names_output
+    # 2. it tends to be a very large value => increases computation time
+    # 3._fzf_search_history is a much better way to examine history anyway
+    set -f all_variable_names (string match --invert history <$set_names_output)
+
+    set -f current_token (commandline --current-token)
+    # Use the current token to pre-populate fzf's query. If the current token begins
+    # with a $, remove it from the query so that it will better match the variable names
+    set -f cleaned_curr_token (string replace -- '$' '' $current_token)
+
+    set -f variable_names_selected (
+        printf '%s\n' $all_variable_names |
+        _fzf_wrapper --preview "_fzf_extract_var_info {} $set_show_output" \
+            --prompt="Variables> " \
+            --preview-window="wrap" \
+            --multi \
+            --query=$cleaned_curr_token \
+            $fzf_variables_opts
+    )
+
+    if test $status -eq 0
+        # If the current token begins with a $, do not overwrite the $ when
+        # replacing the current token with the selected variable.
+        # Uses brace expansion to prepend $ to each variable name.
+        commandline --current-token --replace (
+            if string match --quiet -- '$*' $current_token
+                string join " " \${$variable_names_selected}
+            else
+                string join " " $variable_names_selected
+            end
+        )
+    end
+
+    commandline --function repaint
+end

fish/functions/_fzf_wrapper.fish

@@ -0,0 +1,21 @@
+function _fzf_wrapper --description "Prepares some environment variables before executing fzf."
+    # Make sure fzf uses fish to execute preview commands, some of which
+    # are autoloaded fish functions so don't exist in other shells.
+    # Use --function so that it doesn't clobber SHELL outside this function.
+    set -f --export SHELL (command --search fish)
+
+    # If neither FZF_DEFAULT_OPTS nor FZF_DEFAULT_OPTS_FILE are set, then set some sane defaults.
+    # See https://github.com/junegunn/fzf#environment-variables
+    set --query FZF_DEFAULT_OPTS FZF_DEFAULT_OPTS_FILE
+    if test $status -eq 2
+        # cycle allows jumping between the first and last results, making scrolling faster
+        # layout=reverse lists results top to bottom, mimicking the familiar layouts of git log, history, and env
+        # border shows where the fzf window begins and ends
+        # height=90% leaves space to see the current command and some scrollback, maintaining context of work
+        # preview-window=wrap wraps long lines in the preview window, making reading easier
+        # marker=* makes the multi-select marker more distinguishable from the pointer (since both default to >)
+        set --export FZF_DEFAULT_OPTS '--cycle --layout=reverse --border --height=90% --preview-window=wrap --marker="*"'
+    end
+
+    fzf $argv
+end

fish/functions/fzf_configure_bindings.fish

@@ -0,0 +1,46 @@
+# Always installs bindings for insert and default mode for simplicity and b/c it has almost no side-effect
+# https://gitter.im/fish-shell/fish-shell?at=60a55915ee77a74d685fa6b1
+function fzf_configure_bindings --description "Installs the default key bindings for fzf.fish with user overrides passed as options."
+    # no need to install bindings if not in interactive mode or running tests
+    status is-interactive || test "$CI" = true; or return
+
+    set -f options_spec h/help 'directory=?' 'git_log=?' 'git_status=?' 'history=?' 'processes=?' 'variables=?'
+    argparse --max-args=0 --ignore-unknown $options_spec -- $argv 2>/dev/null
+    if test $status -ne 0
+        echo "Invalid option or a positional argument was provided." >&2
+        _fzf_configure_bindings_help
+        return 22
+    else if set --query _flag_help
+        _fzf_configure_bindings_help
+        return
+    else
+        # Initialize with default key sequences and then override or disable them based on flags
+        # index 1 = directory, 2 = git_log, 3 = git_status, 4 = history, 5 = processes, 6 = variables
+        set -f key_sequences \e\cf \e\cl \e\cs \cr \e\cp \cv # \c = control, \e = escape
+        set --query _flag_directory && set key_sequences[1] "$_flag_directory"
+        set --query _flag_git_log && set key_sequences[2] "$_flag_git_log"
+        set --query _flag_git_status && set key_sequences[3] "$_flag_git_status"
+        set --query _flag_history && set key_sequences[4] "$_flag_history"
+        set --query _flag_processes && set key_sequences[5] "$_flag_processes"
+        set --query _flag_variables && set key_sequences[6] "$_flag_variables"
+
+        # If fzf bindings already exists, uninstall it first for a clean slate
+        if functions --query _fzf_uninstall_bindings
+            _fzf_uninstall_bindings
+        end
+
+        for mode in default insert
+            test -n $key_sequences[1] && bind --mode $mode $key_sequences[1] _fzf_search_directory
+            test -n $key_sequences[2] && bind --mode $mode $key_sequences[2] _fzf_search_git_log
+            test -n $key_sequences[3] && bind --mode $mode $key_sequences[3] _fzf_search_git_status
+            test -n $key_sequences[4] && bind --mode $mode $key_sequences[4] _fzf_search_history
+            test -n $key_sequences[5] && bind --mode $mode $key_sequences[5] _fzf_search_processes
+            test -n $key_sequences[6] && bind --mode $mode $key_sequences[6] "$_fzf_search_vars_command"
+        end
+
+        function _fzf_uninstall_bindings --inherit-variable key_sequences
+            bind --erase -- $key_sequences
+            bind --erase --mode insert -- $key_sequences
+        end
+    end
+end

fish/themes/Dracula Official.theme

@@ -0,0 +1,55 @@
+# Dracula Color Palette
+#
+# Foreground: f8f8f2
+# Selection: 44475a
+# Comment: 6272a4
+# Red: ff5555
+# Orange: ffb86c
+# Yellow: f1fa8c
+# Green: 50fa7b
+# Purple: bd93f9
+# Cyan: 8be9fd
+# Pink: ff79c6
+
+# Syntax Highlighting Colors
+fish_color_normal f8f8f2
+fish_color_command 8be9fd
+fish_color_keyword ff79c6
+fish_color_quote f1fa8c
+fish_color_redirection f8f8f2
+fish_color_end ffb86c
+fish_color_error ff5555
+fish_color_param bd93f9
+fish_color_comment 6272a4
+fish_color_selection --background=44475a
+fish_color_search_match --background=44475a
+fish_color_operator 50fa7b
+fish_color_escape ff79c6
+fish_color_autosuggestion 6272a4
+fish_color_cancel ff5555 --reverse
+fish_color_option ffb86c
+fish_color_history_current --bold
+fish_color_status ff5555
+fish_color_valid_path --underline
+
+# Default Prompt Colors
+fish_color_cwd 50fa7b
+fish_color_cwd_root red
+fish_color_host bd93f9
+fish_color_host_remote bd93f9
+fish_color_user 8be9fd
+
+# Completion Pager Colors
+fish_pager_color_progress 6272a4
+fish_pager_color_background
+fish_pager_color_prefix 8be9fd
+fish_pager_color_completion f8f8f2
+fish_pager_color_description 6272a4
+fish_pager_color_selected_background --background=44475a
+fish_pager_color_selected_prefix 8be9fd
+fish_pager_color_selected_completion f8f8f2
+fish_pager_color_selected_description 6272a4
+fish_pager_color_secondary_background
+fish_pager_color_secondary_prefix 8be9fd
+fish_pager_color_secondary_completion f8f8f2
+fish_pager_color_secondary_description 6272a4

install.sh

@@ -0,0 +1,270 @@
+#!/usr/bin/env bash
+#
+# A script to bootstrap dotfiles with a mapping of repo-file -> home-file:
+# - Clones the repo if needed (when run outside ~/.dotfiles).
+# - Installs packages (different for macOS vs. Ubuntu/Debian).
+# - Changes shell to Fish if it's not already.
+# - Symlinks dotfiles (with custom filename mapping), prompting to replace existing ones.
+
+set -euo pipefail
+
+################################################################################
+# VARIABLES
+################################################################################
+
+DOTFILES_REPO="https://git.straybits.ca/jeff/dotfiles.git"
+DOTFILES_DIR="$HOME/.dotfiles"
+
+# Packages for macOS:
+PACKAGES_MAC=(
+  fish
+  fzf
+  bat
+  ack
+  fd
+  age
+  minisign
+  macvim
+  mc
+  lazygit
+)
+
+# Packages for Linux (assuming Ubuntu/Debian):
+PACKAGES_LINUX=(
+  git
+  fish
+  curl
+  fzf
+  bat
+  ack
+  fd-find
+  age
+  minisign
+  vim-tiny
+  mc
+)
+
+#------------------------------------------------------------------------------
+# Symlinking Dotfiles With Different Filenames
+#
+# In this associative array:
+#   - The key is the file/directory name as it appears in the dotfiles repo.
+#   - The value is the target path you want symlinked in your home directory.
+#------------------------------------------------------------------------------
+SYMLINKS=(
+  "vim/config.vim:$HOME/.vim_runtime/my_configs.vim"
+  "vim/plugins:$HOME/.vim_runtime/my_plugins"
+  "fish:$HOME/.config/fish"
+)
+
+TARGET_SHELL="fish"
+
+################################################################################
+# FUNCTIONS
+################################################################################
+
+detect_os() {
+  local os
+  os="$(uname -s)"
+  case "${os}" in
+      Linux*)   echo "linux" ;;
+      Darwin*)  echo "mac"   ;;
+      *)        echo "unsupported" ;;
+  esac
+}
+
+install_package_linux() {
+  local pkg="$1"
+  # Check if installed:
+  if ! dpkg -s "$pkg" >/dev/null 2>&1; then
+    echo "Installing ${pkg} via apt..."
+    sudo apt-get update -y
+    sudo apt-get install -y "${pkg}"
+  else
+    echo "[OK] ${pkg} is already installed (Linux)."
+  fi
+}
+
+install_package_mac() {
+  local pkg="$1"
+  # Check if installed:
+  if ! brew ls --versions "$pkg" >/dev/null; then
+    echo "Installing ${pkg} via Homebrew..."
+    brew install "${pkg}"
+  else
+    echo "[OK] ${pkg} is already installed (macOS)."
+  fi
+}
+
+install_packages() {
+  local os="$1"
+
+  if [ "${os}" = "mac" ]; then
+    # Make sure Homebrew is installed first
+    if ! command -v brew >/dev/null 2>&1; then
+      echo "Homebrew not found, installing..."
+      /bin/bash -c "$(curl -fsSL https://raw.githubusercontent.com/Homebrew/install/HEAD/install.sh)"
+      # If needed, add brew to PATH (depends on your environment).
+      # Example:
+      # echo 'eval "$(/opt/homebrew/bin/brew shellenv)"' >> "${HOME}/.bashrc"
+      # eval "$(/opt/homebrew/bin/brew shellenv)"
+    fi
+
+    # Install each macOS package if missing
+    for pkg in "${PACKAGES_MAC[@]}"; do
+      install_package_mac "${pkg}"
+    done
+
+  elif [ "${os}" = "linux" ]; then
+    if ! command -v apt-get >/dev/null 2>&1; then
+      echo "Error: This script currently only supports apt-based distros on Linux."
+      exit 1
+    fi
+
+    # Install each Linux package if missing
+    for pkg in "${PACKAGES_LINUX[@]}"; do
+      install_package_linux "${pkg}"
+    done
+
+    # No packages for lazygit on Linux :(
+    install_lazygit_linux
+
+  fi
+}
+
+install_lazygit_linux() {
+    LAZYGIT_VERSION=$(curl -s "https://api.github.com/repos/jesseduffield/lazygit/releases/latest" | \grep -Po '"tag_name": *"v\K[^"]*')
+    arch="$(uname -m)"
+    case "$arch" in
+      x86_64)
+        LAZYGIT_ARCH="Linux_x86_64"
+        ;;
+      aarch64)
+        LAZYGIT_ARCH="Linux_arm64"
+        ;;
+      *)
+        echo "Unsupported architecture: $arch"
+        exit 1
+        ;;
+    esac
+    echo "Downloading LazyGit v${LAZYGIT_VERSION} for ${LAZYGIT_ARCH}..."
+    curl -Lo lazygit.tar.gz \
+      "https://github.com/jesseduffield/lazygit/releases/download/v${LAZYGIT_VERSION}/lazygit_${LAZYGIT_VERSION}_${LAZYGIT_ARCH}.tar.gz"
+    tar xf lazygit.tar.gz lazygit
+    sudo install lazygit -D -t /usr/local/bin/
+    rm -f lazygit.tar.gz lazygit
+}
+
+install_awesome_vim() {
+  if [ ! -d "$HOME/.vim_runtime" ]; then
+    echo "Cloning Amix's vimrc..."
+    git clone --depth=1 https://github.com/amix/vimrc.git "$HOME/.vim_runtime"
+    echo "Installing Awesome Vimrc..."
+    sh "$HOME/.vim_runtime/install_awesome_vimrc.sh"
+  else
+    echo "~/.vim_runtime already exists, skipping clone."
+  fi
+}
+
+install_starship() {
+  if ! command -v starship >/dev/null 2>&1; then
+    echo "Installing Starship"
+    curl -sS https://starship.rs/install.sh | sh
+  else
+    echo "Starship already installed"
+  fi
+}
+
+change_shell_to_fish() {
+  if [[ $SHELL != *"${TARGET_SHELL}"* ]]; then
+    # Check if fish is actually installed
+    echo "Changing default shell to '${TARGET_SHELL}'..."
+    chsh -s "$(command -v fish)"
+  else
+    echo "[OK] Shell is already '${TARGET_SHELL}'."
+  fi
+}
+
+create_symlinks() {
+  # Iterate over the SYMLINKS associative array
+  for pair in "${SYMLINKS[@]}"; do
+    local src="${DOTFILES_DIR}/${pair%%:*}"
+    local dest="${pair#*:}"
+
+    # Ensure the parent directory of the destination exists
+    mkdir -p "$(dirname "${dest}")"
+
+    # Early exit if the link already exists
+    if [ -e "${dest}" ] && [ -L "${dest}" ]; then
+      echo "  -> Link '${dest}' to '${src}' exists."
+      continue
+    fi
+
+    if [ -e "${dest}" ]; then
+      # A real file or directory is in the way
+      read -rp "File '${dest}' already exists. Overwrite? [y/N] " answer
+      if [[ "${answer}" =~ ^[Yy]$ ]]; then
+        rm -rf "${dest}"
+        ln -s "${src}" "${dest}"
+        echo "  -> Overwrote '${dest}' with symlink to '${src}'."
+      else
+        echo "  -> Skipped '${dest}'."
+      fi
+    else
+      ln -s "${src}" "${dest}"
+      echo "  -> Linked '${dest}' to '${src}'."
+    fi
+  done
+}
+
+deploy_dotfiles() {
+  local os
+  os="$(detect_os)"
+
+  if [ "${os}" = "unsupported" ]; then
+    echo "Unsupported OS: $(uname -s). Exiting."
+    exit 1
+  fi
+
+  echo "1. Installing necessary packages..."
+  install_packages "${os}"
+
+  echo "2. Intalling awesome vim..."
+  install_awesome_vim
+
+  echo "3. Intalling Starship..."
+  install_starship
+
+  echo "4. Changing shell to '${TARGET_SHELL}' (if needed)..."
+  change_shell_to_fish
+
+  echo "5. Creating symlinks..."
+  create_symlinks
+
+  echo "Done!"
+}
+
+################################################################################
+# MAIN SCRIPT
+################################################################################
+
+# If the script is not being run from ~/.dotfiles, we assume the user just curl'ed it.
+if [ "$(cd "$(dirname "${BASH_SOURCE[0]}")" && pwd)" != "${DOTFILES_DIR}" ]; then
+  echo "Script is not in ${DOTFILES_DIR}; assuming first-time setup..."
+
+  if [ ! -d "${DOTFILES_DIR}" ]; then
+    echo "Cloning dotfiles repo into ${DOTFILES_DIR}..."
+    git clone "${DOTFILES_REPO}" "${DOTFILES_DIR}"
+  else
+    echo "${DOTFILES_DIR} already exists. Pulling latest changes..."
+    git -C "${DOTFILES_DIR}" pull --rebase
+  fi
+
+  echo "Running deployment from cloned repo..."
+  cd "${DOTFILES_DIR}"
+  bash install.sh  # re-invoke the script from within ~/.dotfiles
+  exit 0
+else
+  echo "Script running from ${DOTFILES_DIR} - proceeding with deployment..."
+  deploy_dotfiles
+fi

vim/config.vim

@@ -0,0 +1 @@
+colorscheme dracula